SQLの窓 イラストAC フリー素材

2018年02月03日

ローカルをあたかも Web につないでるように見せる HOSTS ファイルのエントリの追加



HOSTS ファイルは、ドメイン名やサーバー名といった、IPアドレスに関係づけられた名前から、IP アドレスを特定する為に「最初」に参照されるファイルです。ここに記述した内容は、その PC だけで言えば、世界中のいかなる DNSによる名前解決より優先されます。



ですから、用途としては

1) デモ用 PC(ネットワークなし) の仮のドメインでローカルで動作させる為
2) サーバー環境をローカルのPC で動作(テスト)させる為

に使われます。



なお、エディタで変更する際、管理者権限で起動しないと更新できないので、いったんなんらかの使い慣れたエディタを起動して、CTRL+SHIFT キーを押しながらタスクバーのエディタをクリックして管理者権限でエディタを起動させて使用して下さい




※ 初期投稿 : 2006-11-29



タグ:hosts Windows
【Windowsの最新記事】
posted by at 2018-02-03 17:41 | Windows | このブログの読者になる | 更新情報をチェックする

IE のお気に入りディレクトリにあるファイルの表示・非表示を設定する / HTA(HTML アプリケーション)

VBScript の処理方法を整理する意味で、Windows10 でテストして9年ぶりに更新しました。

※ 昨今、IE は使われ無いようになって行っていますが、まだ当分は必要な環境もあると思います。
このプログラムは、IE のお気に入りディレクトリのファイルの表示・非表示を設定するツールです。 ( C:\Users\ユーザ名\Favorites ) チェックボックスがチェックされていると表示されます。チェックされていないと非表示となります。 更新後、IE は再起動するか、タブを複製すると反映されます(新しいタブでも反映されてました) ▼ エントリをクリックするとプロパティを開きます favdir.hta の内容 ※ 実行するには、拡張子が hta である必要があります
<meta http-equiv="content-type" content="text/html; charset=SHIFT_JIS">
<SCRIPT language="VBScript">

	Dim WshShell,TargetDir,objShell,nId

	Set WshShell = CreateObject( "WScript.Shell" )
	TargetDir = WshShell.SpecialFolders("Favorites")
	Set objShell = CreateObject("Shell.Application")

	Set Fso = CreateObject( "Scripting.FileSystemObject" )

Function SetTable()

	Set objFolder = Fso.GetFolder( TargetDir )
	Set objFiles = objFolder.SubFolders 

	str=""
	str=str&"<TABLE id=ieex border=0 cellspacing=1 cellpadding=6> "&vbCrLf
	str=str&"<TH style='width:35px;'></TH> "&vbCrLf
	str=str&"<TH>エントリをクリックするとプロパティを開きます<br>エントリが二段で下がリンクの場合クリックすると IE で開く事ができます</TH> "&vbCrLf
	str=str&"<TH></TH> "&vbCrLf

	nId = 1
	For each objFile in objFiles

		str=str&"<tr>" & vbCrLf
		str=str&"<td>" & vbCrLf
		' チェックボックス ( check+n )
		str=str&"<input type='checkbox' id=check" & nId

		' hidden の場合
		if objFile.Attributes and 2 then
			' なにもしない
		else
			' 通常表示されている状態
			str=str&" checked "
		end if

		str=str&">"
		str=str&"</td>" & vbCrLf
		str=str&"<td style='background-color:silver;font-weight:bold;'>" & vbCrLf
		str=str&"<input type='button' value='フォルダに移動' onClick='Call ChangeDir("""& TargetDir & "\" & objFile.Name &""")'>&nbsp;"
		str=str&"<span id=target" & nId & " style='cursor:pointer;color:navy;vertical-align:4px' onClick='Call OpenProp(""" & nId & """)'>["

		Set objShellFolder = objShell.NameSpace(TargetDir & "\" & objFile.Name)

		str=str&objShellFolder.Title
		str=str&"]</span>"
		str=str&"</td>" & vbCrLf
		str=str&"<td style='background-color:silver;font-weight:bold;' id=fullpath" & nId & ">"
		str=str&TargetDir & "\" & objFile.Name
		str=str&"</td>" & vbCrLf
		str=str&"</tr>" & vbCrLf

		nId = nId + 1

	Next

	Set objFiles = objFolder.Files

	For each objFile in objFiles

		if Ucase(Right(objFile.Name,4)) = ".URL" then

			str=str&"<tr>" & vbCrLf
			str=str&"<td>" & vbCrLf
			' チェックボックス ( check+n )
			str=str&"<input type='checkbox' id=check" & nId
		
			' hidden の場合
			if objFile.Attributes and 2 then
				' なにもしない
			else
				' 通常表示されている状態
				str=str&" checked "
			end if
		
			str=str&">"
			str=str&"</td>" & vbCrLf
			str=str&"<td>" & vbCrLf
			str=str&"<span id=target" & nId & " style='cursor:pointer;color:navy' onClick='Call OpenProp(""" & nId & """)'>"
			str=str&objFile.Name
			str=str&"</span>"
		
			str=str&"<br>"
			Set oUrlLink = WshShell.CreateShortcut(TargetDir & "\" & objFile.Name)
			if Ucase(Left(Trim(oUrlLink.TargetPath),11)) <> "JAVASCRIPT:" then
				str=str&"<a style='color:blue;' href='"
				str=str&oUrlLink.TargetPath
				str=str&"' target=_blank>"&oUrlLink.TargetPath&"</a>"
			end if
		
			str=str&"</td>" & vbCrLf
			str=str&"<td id=fullpath" & nId & ">"
			str=str&TargetDir & "\" & objFile.Name
			str=str&"</td>" & vbCrLf
			str=str&"</tr>" & vbCrLf
		
			nId = nId + 1

		end if

	Next

	nId = nId - 1

	str=str&"</TABLE>"&vbCrLf

	document.getElementById("table").innerHTML = str

End Function

Function OpenProp( nRow )

	Dim str,str1,str2

	str = document.getElementById("fullpath"&nRow).innerText

	Dim objWork,bFlg

	if Ucase(document.getElementById("fullpath"&nRow).style.backgroundColor) = "SILVER" then
		Set objWork = Fso.GetFolder(str)
	else
		Set objWork = Fso.GetFile( str )
	end if
	bFlg = False
	if (objWork.Attributes and 2) = 2 then
		objWork.Attributes = objWork.Attributes and (255-2)
		bFlg = True
	end if

	Set objFolder = objShell.NameSpace(TargetDir)

	For each objFile in objFolder.items
		if str = objFile.Path then
			Set obj = objFile.Verbs
			For i = 0 To obj.Count - 1
				if InStr( obj.item(i).Name, "プロパティ" ) > 0 then
					objFile.InvokeVerb("Properties")
				end if
			Next
		end if
	Next

	if bFlg then
		objWork.Attributes = objWork.Attributes or 2
	end if

End Function

Function AttUpdate()

	Dim idx,str,work,objFile

	For idx = 1 to nId
		' 対象となるパス
		str = document.getElementById("fullpath"&idx).innerText

		if Ucase(document.getElementById("fullpath"&idx).style.backgroundColor) = "SILVER" then
			' ファイルオブジェクト
			Set objFile = Fso.GetFolder(str)
		else
			' ファイルオブジェクト
			Set objFile = Fso.GetFile(str)
		end if

		if document.getElementById("check"&idx).checked then
			' チェックされているので hidden を除く
			objFile.Attributes = objFile.Attributes and (255-2)
		else
			' チェックが外されているので hidden を設定する
			objFile.Attributes = objFile.Attributes or 2
		end if
	Next

	alert("更新しました   ")

End Function

Function ChangeDir( path )

	TargetDir = path

	Call SetTable()

	document.title = path

End Function

</SCRIPT>
<html>
<head>
<title>お気に入り ディレクトリ/メンテナンス</title>
<HTA:APPLICATION ID="Sqlwin"
	BORDERSTYLE="sunken"
	INNERBORDER="yes"
	SCROLL="yes"
	ICON="http://winofsql.jp/WinOfSql.ico"
>
<style type="text/css">
* {
	font-size:12px;
	font-family: "メイリオ";
}
body {
	margin:0;
}

#ieex {
	table-layout:fixed;
	margin-top:4px;
	margin-left:20px;
	width:1000px;
	background-color:black;
}

#ieex td,#ieex th {
	background-color:white;
}

#update {
	margin-top:0px;
	margin-left:20px;
}

</stylE>
</head>
<body>
<div style='padding:5px 20px;font-size:16px;font-weight:bold'>IE のお気に入りディレクトリにあるファイルの表示・非表示を設定する</div>
<div style='width:1000px;'>
	<input style='float:right' type="button" value="HOME" onclick='TargetDir = WshShell.SpecialFolders("Favorites"):Call SetTable():document.title = "お気に入り ディレクトリ/メンテナンス"'>
	<input id=update type=button value="更新" onClick='Call AttUpdate()'> <span style='vertical-align:4px'>チェックを外して更新すると、IE 側で表示だけしなくなります(<b>IE は再起動するか、タブを複製して下さい</b>)。</span>
</div>
<div id=table>

</BODY>
</html>
<SCRIPT for=window event=onload language="VBScript">

	window.focus()
	top.moveTo 0, 0
	top.resizeTo screen.width, screen.height - 32

	Call SetTable()

</SCRIPT>

<SCRIPT for=window event=onunload language="VBScript">

</SCRIPT>




posted by at 2018-02-03 14:32 | VBScript | このブログの読者になる | 更新情報をチェックする

2018年01月30日

VBScript : デスクトップの列挙

オンライン上にある、VBScript のライブラリを使用しています。
<JOB>
<COMMENT>
************************************************************
 WSH 実行スケルトン
************************************************************
</COMMENT>

<COMMENT>
************************************************************
 外部スクリプト定義
************************************************************
</COMMENT>
<SCRIPT
	language="VBScript"
	src="http://lightbox.in.coocan.jp/laylaClass.vbs">
</SCRIPT>

<SCRIPT language=VBScript>
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://lightbox.in.coocan.jp/" )
Call laylaLoadFunction( "baseFunction.vbs" )

GetShell

Crun2 130

Wscript.Echo "【デスクトップ/一般】"
Wscript.Echo "----------------------------------------------------"
Set objFolder = Shell.NameSpace( 0 )

Set objFolderItems = objFolder.Items()
nCount = objFolderItems.Count

' 列挙1
strData = ""
For i = 0 to nCount - 1

	strData = strData & RpadB(objFolderItems.Item(i).Name," ",30 )
'	strData = strData & RpadB(objFolderItems.Item(i).ModifyDate," ",30 )
	strData = strData & RpadB(objFolderItems.Item(i).Path," ",89 )
'	strData = strData & RpadB(objFolderItems.Item(i).Size," ",20 )
'	strData = strData & RpadB(objFolderItems.Item(i).Type," ",20 )
	WScript.Echo strData
	strData = ""

Next


' 列挙2
Wscript.Echo
Wscript.Echo "【デスクトップ/詳細情報】"
Wscript.Echo "----------------------------------------------------"
strData = ""
For Each obj In objFolderItems

	strData = strData & RpadB(objFolder.GetDetailsOf(obj, 0)," ",20 )
	strData = strData & RpadB(objFolder.GetDetailsOf(obj, 1)," ",20 )
	strData = strData & RpadB(objFolder.GetDetailsOf(obj, 2)," ",20 )
	strData = strData & RpadB(objFolder.GetDetailsOf(obj, 3)," ",20 )
	strData = strData & RpadB(objFolder.GetDetailsOf(obj, 4)," ",20 )
	strData = strData & RpadB(objFolder.GetDetailsOf(obj, -1)," ",20 )
	WScript.Echo strData
	strData = ""

Next

Wscript.Echo

</SCRIPT>
</JOB>



▼ Windows10 での実行結果サンプル


結果をテキストファイルに残すには、以下のようにして表示をファイルにリダイレクトします
cscript ginpro_1517239356526.wsf > log.txt
一部特殊フォルダが表示されていますが、それらを使用してエクスプローラを起動する事ができます。Winows10 で、PC を選択してエクスプローラを開く記述は以下のようになります。
Explorer /e,/root,::{20D04FE0-3AEA-1069-A2D8-08002B30309D}



posted by at 2018-01-30 17:25 | VBScript | このブログの読者になる | 更新情報をチェックする

2018年01月28日

バッチ処理の為の .wsf スケルトン / cscript.exe での実行を強制する / 自分自身の呼び出し

Wscript.Echo は、Wscript.exe から実行すると、一回の処理毎にメッセージボックスを表示するので、連続処理する場合は避けなければなりません(wscript.exe をタスクマネージャから強制終了する事になります)

Wscript.exe は、通常エクスプローラからダブルクリックでスクリプトを実行した際に使用されるので、誤って実行してしまう事を避ける方法です。以下のサンプルでは、スクリプトにデータを含めて、そのデータをループ処理で表示する処理ですが、コマンドプロンプトからの実行を強制しています( コマンドプロンプトから、cscript.exe を使用しないと Quit されます )


右端のアイコンよりダウンロードできます
<JOB>
<SCRIPT language="VBScript">

' コマンドプロンプトより起動される為の処理
str = WScript.FullName
str = Right( str, 11 )
str = Ucase( str )
if str <> "CSCRIPT.EXE" then
	strMessage = "コマンドプロンプトより cscript " & WScript.ScriptFullName
	strMessage = strMessage & " と指定して実行して下さい   " & vbCrLf & vbCrLf
	strMessage = strMessage & "( この文字列をクリップボードにコピーした場合は"
	strMessage = strMessage & "ctrl+c です )"
	WScript.Echo strMessage
	WScript.Quit
end if

aData = Split( getResource("myText"), vbCrLf )
For I = 0 to Ubound( aData )
	if Trim( aData(I) ) <> "" then
		Wscript.Echo aData(I)
	end if
Next

</SCRIPT>

<RESOURCE id="myText">
コード名称マスタ
商品マスタ
得意先マスタ
社員マスタ
取引データ
</RESOURCE>
</JOB>

以下はオンラインのライブラリの Crun と言う関数を使って、Wscript.exe で起動された場合は、cscript.exe で自分自身を呼び出して再度実行しています( 最後にコマンドプロンプトの pause で停止 )
右端のアイコンよりダウンロードできます
<JOB>
<SCRIPT language="VBScript" src="http://lightbox.in.coocan.jp/laylaClass.vbs"></SCRIPT>
<SCRIPT language="VBScript">
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://lightbox.in.coocan.jp/" )
Call laylaLoadFunction( "baseFunction.vbs" )

Crun()

aData = Split( getResource("myText"), vbCrLf )
For I = 0 to Ubound( aData )
	if Trim( aData(I) ) <> "" then
		Wscript.Echo aData(I)
	end if
Next

</SCRIPT>

<RESOURCE id="myText">
コード名称マスタ
商品マスタ
得意先マスタ
社員マスタ
取引データ
</RESOURCE>
</JOB>


上記内容をオンラインなしで実行するには、以下のようになります
右端のアイコンよりダウンロードできます
<JOB>
<SCRIPT language="VBScript">

' コマンドプロンプトより起動される為の処理
str = WScript.FullName
str = Right( str, 11 )
str = Ucase( str )
if str <> "CSCRIPT.EXE" then
	str = WScript.ScriptFullName
	Set WshShell = Wscript.CreateObject("WScript.Shell")
	strParam = " "
	For I = 0 to Wscript.Arguments.Count - 1
		if instr(Wscript.Arguments(I), " ") < 1 then
			strParam = strParam & Wscript.Arguments(I) & " "
		else
			strParam = strParam & """" & Wscript.Arguments(I) & """ "
		end if
	Next
	Call WshShell.Run( "cmd.exe /c cscript.exe """ & str & """" & strParam & " & pause", 3 )
	WScript.Quit
end if

aData = Split( getResource("myText"), vbCrLf )
For I = 0 to Ubound( aData )
	if Trim( aData(I) ) <> "" then
		Wscript.Echo aData(I)
	end if
Next

</SCRIPT>

<RESOURCE id="myText">
コード名称マスタ
商品マスタ
得意先マスタ
社員マスタ
取引データ
</RESOURCE>
</JOB>




posted by at 2018-01-28 01:06 | VBScript | このブログの読者になる | 更新情報をチェックする

2018年01月27日

【VBS汎用】SHIFT_JISデータを各種キャラクタセットのテキストファイルへ変換

Microsoft のデータはメモ帳でも解るように、SHIFT_JIS と Unicode と (UTF8) しか通常では対応していないので、このような処理が実は結構必要になります。

しかし、このような方法はたぶんあまり知られて無いので、他のアプリケーションを利用している場合が多いのでは無いでしょうか。(というか、そもそもファイルシステムオブジェクトで UTF8、UTF8N、EUC-JP を対応しろって思いますけど。)

変換は全てメモリ上で処理します。

外部ライブラリを WEB 上に置いて読み込んで処理しているので、その部分は『コマンド』だと思って下さい。
例) Crun は、コマンドプロンプトでの実行を強制します


VBScript の中に埋め込んだデータはファイルとしては Shift_JIS です。VBScript のインタープリタの内部的には Unicode ですが、何も考えなければ出力されたデータは Shift_JIS になってしまいます。

これを 5 種類のキャラクタセットとして意図的に出力します
1) SHIFT_JIS
2) UNICODE
3) EUC-JP
4) UTF8
5) UTF8N
※ UTF8 が少し特殊です(BOMを付加しています)
右端のアイコンよりダウンロードできます
<JOB>
<SCRIPT
	language="VBScript"
	src="http://lightbox.in.coocan.jp/laylaClass.vbs">
</SCRIPT>

<SCRIPT language=VBScript>
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://lightbox.in.coocan.jp/" )
Call laylaLoadFunction( "baseFunction.vbs" )

' Csript.exe で実行を強制
Crun

' 元となる shift_jis の文字列
strShiftJis = GetInline("shift_jis")

' このディレクトリ
strDir = ScriptDir()

' ファイルシステムオブジェクト作成
GetFso

' 出力パス
strPath1 = strDir & "\sjis.txt"
strPath2 = strDir & "\unicode.txt"
strPath3 = strDir & "\ujis.txt"
strPath4 = strDir & "\utf8.txt"
strPath5 = strDir & "\utf8n.txt"

' ファイルシステムオブジェクトで、sjis と unicode
Call PutTextFile( strPath1, strShiftJis )
Call PutTextFileUnicode( strPath2, strShiftJis )

' キャラクタセット変換用の Stream オブジェクト
Set Stream = Wscript.CreateObject("ADODB.Stream")
Set Stream2 = Wscript.CreateObject("ADODB.Stream")

' 開く
Stream.Open
Stream2.Open
' 二つ目はバイナリ専用
Stream2.Type = 1

Stream.Charset = "euc-jp"
Stream.WriteText strShiftJis
Stream.SaveToFile strPath3, 2

' 先頭に移動
Stream.Position = 0
Stream.Charset = "utf-8"
Stream.WriteText strShiftJis
Stream.SaveToFile strPath4, 2

' バイナリにコピー
Stream.CopyTo Stream2

' 一つ目もバイナリにする為、いったん閉じる
Stream.Close
' 再度開いてバイナリにする
Stream.Open
Stream.Type = 1

' バイナリを読んでバイナリに書く
Stream2.Position = 0
Stream2.Read(3)
Do while not Stream2.EOS
	Stream.Write Stream2.Read(16)
Loop

' utn-8n
Stream.SaveToFile strPath5, 2


' 閉じる
Stream2.Close
Stream.Close


print "処理が終了しました"
print ""

Wscript.Quit

</SCRIPT>

<RESOURCE id="shift_jis">
<![CDATA[
ここは、VBScript なので shift_jis になります。
必要に応じてキャラクタセットを変更します
]]>
</RESOURCE>

</JOB>




posted by at 2018-01-27 21:48 | VBScript | このブログの読者になる | 更新情報をチェックする

2018年01月20日

いろいろな言語におけるバーセントエンコーディング

2014年04月07日 作成

※ PHP に関しては、5.6.30 と 7.0.8 で変化はありません
  • 【1】 PHP : urlencode
  • 【2】 PHP : rawurlencode : 5.2.x
  • 【3】 PHP : rawurlencode : 5.3.x (rfc3986)
  • 【4】 JavaScript : encodeURI
  • 【5】 JavaScript : encodeURIComponent
  • 【6】 ASP : Server.URLEncode ( Server.URLEncode(chr(I))で変換できない文字があります )
  • 【7】 PowerShell : [System.Web.HttpUtility]::UrlEncode
  • 【8】 python 2.6.2
1〜8 はかなり前に調べたものですが、以下は今回調べました。 結果さえ解っておれば、一括で置き換えるのが簡単です( rfc3986 対応 )
  • 【9】 fw4 : VS2010 Uri.EscapeDataString
  • 【10】 fw4.5 : VS2012 Uri.EscapeDataString (rfc3986)
  • 【11】 fw : VS2010 HttpUtility.UrlEncode( VS2012 も同じ )
ちなみに、Framework4.5 で、WebUtility.UrlEncode があるようで、11) と同じでした。
    php1 php2 php3 js1 js2 asp ps py fw4 fw4.5 fw
    1 2 3 4 5 6 7 8 9 10 11
0   %00 %00 %00 %00 %00   %00 %00 %00 %00 %00
32   + %20 %20 %20 %20 + + %20 %20 %20 +
33 【!】 %21 %21 %21 ! ! %21 ! %21 ! %21 !
34 【"】 %22 %22 %22 %22 %22 %22 %22 %22 %22 %22 %22
35 【#】 %23 %23 %23 # %23 %23 %23 %23 %23 %23 %23
36 【$】 %24 %24 %24 $ %24 %24 %24 %24 %24 %24 %24
37 【%】 %25 %25 %25 %25 %25 %25 %25 %25 %25 %25 %25
38 【&】 %26 %26 %26 & %26 %26 %26 %26 %26 %26 %26
39 【'】 %27 %27 %27 ' ' %27 ' %27 ' %27 %27
40 【(】 %28 %28 %28 ( ( %28 ( %28 ( %28 (
41 【)】 %29 %29 %29 ) ) %29 ) %29 ) %29 )
42 【*】 %2A %2A %2A * * %2A * %2A * %2A *
43 【+】 %2B %2B %2B + %2B %2B %2B %2B %2B %2B %2B
44 【,】 %2C %2C %2C , %2C %2C %2C %2C %2C %2C %2C
45 【-】 - - - - - %2D - - - - -
46 【.】 . . . . . %2E . . . . .
47 【/】 %2F %2F %2F / %2F %2F %2F / %2F %2F %2F
ここは、0から9の数字で変換されません
58 【:】 %3A %3A %3A : %3A %3A %3A %3A %3A %3A %3A
59 【;】 %3B %3B %3B ; %3B %3B %3B %3B %3B %3B %3B
60 【<】 %3C %3C %3C %3C %3C %3C %3C %3C %3C %3C %3C
61 【=】 %3D %3D %3D = %3D %3D %3D %3D %3D %3D %3D
62 【>】 %3E %3E %3E %3E %3E %3E %3E %3E %3E %3E %3E
63 【?】 %3F %3F %3F ? %3F %3F %3F %3F %3F %3F %3F
64 【@】 %40 %40 %40 @ %40 %40 %40 %40 %40 %40 %40
ここは、AからZのアルファベットで変換されません
91 【[】 %5B %5B %5B %5B %5B %5B %5B %5B %5B %5B %5B
92 【\】 %5C %5C %5C %5C %5C %5C %5C %5C %5C %5C %5C
93 【]】 %5D %5D %5D %5D %5D %5D %5D %5D %5D %5D %5D
94 【^】 %5E %5E %5E %5E %5E %5E %5E %5E %5E %5E %5E
95 【_】 _ _ _ _ _ %5F _ _ _ _ _
96 【`】 %60 %60 %60 %60 %60 %60 %60 %60 %60 %60 %60
ここは、aからzのアルファベット(小文字)で変換されません
123 【{】 %7B %7B %7B %7B %7B %7B %7B %7B %7B %7B %7B
124 【|】 %7C %7C %7C %7C %7C %7C %7C %7C %7C %7C %7C
125 【}】 %7D %7D %7D %7D %7D %7D %7D %7D %7D %7D %7D
126 【~】 %7E %7E ~ ~ ~ %7E %7E %7E ~ ~ %7E
127   %7F %7F %7F %7F %7F %7F %7F %7F %7F %7F %7F

PHP rawurlencode
<?php

print rawurlencode (chr(0)) . "\n";
print rawurlencode (chr(32)) . "\n";
print rawurlencode (chr(33)) . "\n";
print rawurlencode (chr(34)) . "\n";
print rawurlencode (chr(35)) . "\n";
print rawurlencode (chr(36)) . "\n";
print rawurlencode (chr(37)) . "\n";
print rawurlencode (chr(38)) . "\n";
print rawurlencode (chr(39)) . "\n";
print rawurlencode (chr(40)) . "\n";
print rawurlencode (chr(41)) . "\n";
print rawurlencode (chr(42)) . "\n";
print rawurlencode (chr(43)) . "\n";
print rawurlencode (chr(44)) . "\n";
print rawurlencode (chr(45)) . "\n";
print rawurlencode (chr(46)) . "\n";
print rawurlencode (chr(47)) . "\n";

print rawurlencode (chr(58)) . "\n";
print rawurlencode (chr(59)) . "\n";
print rawurlencode (chr(60)) . "\n";
print rawurlencode (chr(61)) . "\n";
print rawurlencode (chr(62)) . "\n";
print rawurlencode (chr(63)) . "\n";
print rawurlencode (chr(64)) . "\n";
print rawurlencode (chr(91)) . "\n";
print rawurlencode (chr(92)) . "\n";
print rawurlencode (chr(93)) . "\n";
print rawurlencode (chr(94)) . "\n";
print rawurlencode (chr(95)) . "\n";
print rawurlencode (chr(96)) . "\n";
print rawurlencode (chr(123)) . "\n";
print rawurlencode (chr(124)) . "\n";
print rawurlencode (chr(125)) . "\n";
print rawurlencode (chr(126)) . "\n";
print rawurlencode (chr(127)) . "\n";

?>



posted by at 2018-01-20 15:23 | インターネット | このブログの読者になる | 更新情報をチェックする


Android SDK ポケットリファレンス
改訂版 Webデザイナーのための jQuery入門
今すぐ使えるかんたん ホームページ HTML&CSS入門
XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX